判別剪貼板上所有可用的格式

領測軟件測試網 判別剪貼板上所有可用的格式，包括自定義格式

　　在VB允許你判別標準的、認可的格式是否在剪貼板上的同時，你無法判別是否有其它格式出現。所以，舉例來說，如果你想知道剪貼板上是否包含來自Excel的數據(which always pastes at least its own customised format called 'Wk1')，或者你想判別Rich Text格式是否可用以激活粘貼菜單時，你無法辦到。
　　這則技巧告訴你如何判別當前剪貼板上所有可用的格式，包括自定義格式。
　　開始一個新項目，在窗體上放置一個Command和一個ListBox，然后加入下列代碼：

Private Declare Function CountClipboardFormats Lib "USER32" () As Long
Private Declare Function EnumClipboardFormats Lib "USER32" (ByVal wFormat As Long) As Long
Private Declare Function OpenClipboard Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function CloseClipboard Lib "USER32" () As Long
Private Declare Function GetClipboardFormatName Lib "USER32" Alias "GetClipboardFormatNameA" (ByVal wFormat As Long, ByVal lpString As String, ByVal nMaxCount As Long) As Long
Private Enum EPredefinedClipboardFormatConstants
　　[_First] = 1
　　CF_TEXT = 1
　　CF_BITMAP = 2
　　CF_METAFILEPICT = 3
　　CF_SYLK = 4
　　CF_DIF = 5
　　CF_TIFF = 6
　　CF_OEMTEXT = 7
　　CF_DIB = 8
　　CF_PALETTE = 9
　　CF_PENDATA = 10
　　CF_RIFF = 11
　　CF_WAVE = 12
　　CF_UNICODETEXT = 13
　　CF_ENHMETAFILE = 14
　　CF_HDROP = 15
　　CF_LOCALE = 16
　　CF_MAX = 17
　　[_Last] = 17
End Enum

Private Property Get FormatName(ByVal lFormatId As Long) As String
'返回一個見剪貼板格式id的格式名：
Dim lSize As Long
Dim sBuf As String
Dim lR As Long
　　
　　If (lFormatId >= EPredefinedClipboardFormatConstants.[_First] And _
　lFormatId <= EPredefinedClipboardFormatConstants.[_Last]) Then
　　　　'對于預先定義的已知格式，我們自己給出格式名：
　　　　Select Case lFormatId
　　　　Case CF_TEXT
　　　　　　FormatName = "Text"
　　　　Case CF_BITMAP
　　　　　　FormatName = "Bitmap Picture"
　　　　Case CF_METAFILEPICT
　　　　　　FormatName = "Meta-File Picture"
　　　　Case CF_SYLK
　　　　　　FormatName = "Microsoft Symbolic Link (SYLK) data."
　　　　Case CF_DIF
　　　　　　FormatName = "Software Arts' Data Interchange information."
　　　　Case CF_TIFF = 6
　　　　　　FormatName = "Tagged Image File Format (TIFF) Picture"
　　　　Case CF_OEMTEXT
　　　　　　FormatName = "Text (OEM)"
　　　　Case CF_DIB
　　　　　　FormatName = "DIB Bitmap Picture"
　　　　Case CF_PALETTE
　　　　　　FormatName = "Colour Palette"
　　　　Case CF_PENDATA
　　　　　　FormatName = "Pen Data"
　　　　Case CF_RIFF
　　　　　　FormatName = "RIFF Audio data"
　　　　Case CF_WAVE
　　　　　　FormatName = "Wave File"
　　　　Case CF_UNICODETEXT
　　　　　　FormatName = "Text (Unicode)"
　　　　Case CF_ENHMETAFILE
　　　　　　FormatName = "Enhanced Meta-File Picture"
　　　　Case CF_HDROP
　　　　　　FormatName = "File List"
　　　　Case CF_LOCALE
　　　　　　FormatName = "Text Locale Identifier"
　　　　End Select
　　Else
　　　　'對于自定義格式，我們可以向剪貼板要注冊過的名字：
　　　　lSize = 255
　　　　sBuf = String$(lSize, 0)
　　　　lR = GetClipboardFormatName(lFormatId, sBuf, lSize)
　　　　If (lR <> 0) Then
　　　　　　FormatName = Left$(sBuf, lR)
　　　　End If
　　End If
End Property

Private Sub Command1_Click()
Dim lR As Long
Dim iCount As Long
　　
　　List1.Clear
　　If (OpenClipboard(Me.hWnd)) Then
　　　　lR = EnumClipboardFormats(0)
　　　　If (lR <> 0) Then
　　　　　　Do
　　　　　　　　iCount = iCount + 1
　　　　　　　　List1.AddItem FormatName(lR)
　　　　　　　　List1.ItemData(List1.NewIndex) = lR
　　　　　　　　lR = EnumClipboardFormats(lR)
　　　　　　Loop While lR <> 0
　　　　End If
　　End If
　　CloseClipboard
End Sub

　　當你點擊Command后，ListBox將被可用的數據格式列表填充。列表區被設為格式名，每一格的數據被設為剪貼板格式的ID。要在列表中看到自定義格式，試試在點擊Command之前，從Word、寫字板或Inte.net Explorer中復制一些東西。

延伸閱讀

文章來源于領測軟件測試網 http://www.kjueaiud.com/