Windows未公開函數揭密——之二

Windows未公開函數揭密——之二

http://www.applevb.com
 上一次我向大家介紹了如何利用Windows未公開函數實現關閉或重新啟動Windows的功能。在這一期內我要向大家介紹如何使用Windows未公開函數實現調用Windows系統中的一些對話框的功能。其中包括如何調用系統的“運行程序“對話框、”查找文件“對話框、更改與文件相關聯的圖標對話框等等。
 首先在VB中建立一個新的工程文件，然后在Form1中加入五個CommandButton控件，不要改變它們的屬性，然后在Form1的代碼窗口中加入以下代碼：

Option Explicit

Private Type BrowseInfo
     hwndOwner As Long
     pIDLRoot As Long
     pszDisplayName As Long
     lpszTitle As Long
     ulFlags As Long
     lpfnCallback As Long
     lParam As Long
     iImage As Long
End Type

Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260

Private Declare Function SHObjectProperties Lib "Shell32" Alias "#178" _
        (ByVal hwndOwner As Long, _
        ByVal uFlags As Long, _
        ByVal lpstrName As String, _
        ByVal lpstrPar As String) As Long

Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function SHBrowseForFolder Lib "Shell32" (lpbi _
        As BrowseInfo) As Long
Private Declare Function SHFindFiles Lib "Shell32" Alias "#90" _
        (ByVal pIDLRoot As Long, _
        ByVal pidlSavedSearch As Long) As Long
       
Private Declare Function GetFileNameFromBrowse Lib "Shell32" Alias "#63" ( _
        ByVal hwndOwner As Long, _
        ByVal lpstrFile As String, _
        ByVal nMaxFile As Long, _
        ByVal lpstrInitDir As String, _
        ByVal lpstrDefExt As String, _
        ByVal lpstrFilter As String, _
        ByVal lpstrTitle As String) As Long

Private Declare Sub PickIconDlg Lib "Shell32" Alias "#62" (ByVal hwndOwner As Long, _
        ByVal lpstrFile As String, ByVal nMaxFile As Long, lpdwIconIndex As Long)

Private Declare Function SHRunFileDlg Lib "Shell32" Alias "#61" _
        (ByVal hOwner As Long, _
        ByVal hIcon As Long, _
        ByVal lpstrDirectory As String, _
        ByVal szTitle As String, _
        ByVal szPrompt As String, _
        ByVal uFlags As Long) As Long

Private Sub Command1_Click()
    SHRunFileDlg Form1.hWnd, Form1.Icon.Handle, "c:\windows", "運行程序演示", _
        "在文本框中輸入程序名或按瀏覽鍵查找程序", 0
End Sub

Private Sub Command2_Click()
    Dim a As Long
    Dim astr As String
   
    astr = "c:\windows\notepad.exe"
    PickIconDlg Form1.hWnd, astr, 1, a
End Sub

Private Sub Command3_Click()
    Dim astr As String * 256
    Dim bstr As String
   
    bstr = "c:\windows"
    GetFileNameFromBrowse Form1.hWnd, astr, 256, bstr, "*.txt", _
            "文本文件 *.txt", "Open Sample"
    Debug.Print astr
End Sub

Private Sub Command4_Click()
    Dim lpIDList As Long
    Dim udtBI As BrowseInfo

    '初試化udtBI結構
    With udtBI
        .hwndOwner = Form1.hWnd
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With
   
    '彈出文件夾查看窗口
    lpIDList = SHBrowseForFolder(udtBI)
    
    If lpIDList Then
        '查找文件
        SHFindFiles lpIDList, 0
        Call CoTaskMemFree(lpIDList)
    End If
End Sub

Private Sub Command5_Click()
    SHObjectProperties Form1.hWnd, 2, "c:\windows\notepad.exe", "Samples"
End Sub

Private Sub Form_Load()
    Command1.Caption = "運行程序"
    Command2.Caption = "更改圖標"
    Command3.Caption = "打開文件"
    Command4.Caption = "查找文件"
    Command5.Caption = "顯示文件屬性"
End Sub
 
 運行程序，分別點擊不同的按鈕，就可以看到不同的按鈕實現了對不同的系統對話框的調用。