在彈出模態對話框(消息框)的同時設置他的位置

'在彈出模態對話框的同時設置他的位置
'本例子掩飾與父窗體左上角對齊
'根據BCB_FANS(四大名捕之追殺令)的bcb代碼改寫為vb的
'僅供參考
'附BCB_FANS源代碼
'BCB_FANS (四大名捕之追殺令)
'當MessageBox對話框顯示的時候，主窗口將失去焦點，知道了這一點，問題就很簡單了。下面是我的C++Builder代碼。
'
'//替換主窗口的窗口過程（我不知道VC怎樣辦到這一點，反正原理就是這樣）
'
'void __fastcall TForm1::WndProc(Messages::TMessage &Message)
'{
'  TForm::WndProc(Message);
'
'  //失去焦點之前
'  if(Message.Msg == WM_NCACTIVATE)
'  {
'  }
'  //失去焦點之后
'  else if(Message.Msg == WM_ACTIVATE)
'  {
'    if(LOWORD(Message.WParam) == WA_INACTIVE)
'    {
'      HWND hWnd;
'      char ClassBuf[64];
'
'      hWnd = (HWND)Message.LParam;
'      GetClassName(hWnd,ClassBuf,sizeof(ClassBuf));
'
'      //首先判斷是否是MessageBox對話框，
'      if(AnsiString(ClassBuf) == "#32770")
'      {
'        //再判斷這個窗口是否是本身程序的窗口（因為別的程序彈出窗口時，你的主窗口也同樣失去焦點）
'        DWORD dwProcessID;
'
'        GetWindowThreadProcessId(hWnd,&dwProcessID);
'
'        if(dwProcessID == GetCurrentProcessId())
'        {
'          //移動窗口的位置
'          MoveWindow(.......);//或者調用 SetWindowPos(...)
'
'          //替換左邊的標題欄圖標(如果有的話)
'          SetClassLong(hWnd,GCL_HICON,(long)Image1->Picture->Icon->Handle);
'
'          //重新設置按鈕的文本（比如把確定改為“OK 007”）
'          HWND hTemp;
'
'          hTemp = GetDlgItem(hWnd,1);
'          SetWindowText(hTemp,"New Text For Button");
'
'          //.........其他操作
'        }
'      }
'    }
'  }
'}

'窗體

Option Explicit
Private Sub Form_Load()
    On Error Resume Next
   
    lhSysMenu = GetSystemMenu(hwnd, 0&)
    lRet = AppendMenu(lhSysMenu, MF_SEPARATOR, 0&, vbNullString)
    lRet = AppendMenu(lhSysMenu, MF_STRING, IDM_ABOUT, "About...")
    Show
   
    ProcOld = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
    Dim r As RECT
    Dim p As POINTAPI
    If Button = vbRightButton Then
        GetCursorPos p
        TrackPopupMenu lhSysMenu, 0, p.x, p.y, 0, Me.hwnd, r
    End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
    SetWindowLong hwnd, GWL_WNDPROC, ProcOld
End Sub

'模塊

Option Explicit
Public Declare Function TrackPopupMenu Lib "user32" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal x As Long, ByVal y As Long, ByVal nReserved As Long, ByVal hwnd As Long, lprc As RECT) As Long
Public Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function AppendMenu Lib "user32" Alias "AppendMenuA" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpNewItem As String) As Long
Public Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, ByVal bRevert As Long) As Long
Public Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
Public Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Public Declare Function GetCurrentProcessId Lib "kernel32" () As Long
Public Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Public Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Public Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type
Public Type POINTAPI
        x As Long
        y As Long
End Type
Public ProcOld As Long
Public Const TPM_LEFTALIGN = &H0&
Public Const WM_SYSCOMMAND = &H112
Public Const MF_SEPARATOR = &H800&
Public Const MF_STRING = &H0&
Public Const GWL_WNDPROC = (-4)
Public Const IDM_ABOUT As Long = 1010
Public Const WM_COMMAND = &H111
Public Const WM_ACTIVATE = &H6
Public Const WA_INACTIVE = 0

Public lhSysMenu As Long, lRet As Long

Public Function WindowProc(ByVal hwnd As Long, ByVal iMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Select Case iMsg
    Case WM_SYSCOMMAND
        If wParam = IDM_ABOUT Then
            MsgBox "VB Move Messagebox demo", vbInformation, "About"
            Exit Function
        End If
    Case WM_COMMAND
        If wParam = IDM_ABOUT Then
            MsgBox "VB Move Messagebox demo", vbInformation, "About"
            Exit Function
        Else
            CallWindowProc ProcOld, hwnd, WM_SYSCOMMAND, wParam, lParam
            WindowProc = 0
            Exit Function
        End If
    Case WM_ACTIVATE
        If wParam = WA_INACTIVE Then
            Dim mywnd As Long
            Dim buf As String * 64
            Dim oldrect As RECT
            GetWindowRect hwnd, oldrect
            mywnd = lParam
            GetClassName mywnd, buf, 64
            If Mid(buf, 1, 6) = "#32770" Then
                Dim processid As Long
                GetWindowThreadProcessId mywnd, processid
                If processid = GetCurrentProcessId() Then
                    SetWindowPos mywnd, 0, oldrect.Left, oldrect.Top, oldrect.Right - oldrect.Left, oldrect.Bottom - oldrect.Top, 0
                End If
            End If
        End If
    End Select
    WindowProc = CallWindowProc(ProcOld, hwnd, iMsg, wParam, lParam)
End Function