PowerDesigner腳本：刪除無用的Data Items

'*****************************************************************************
'文件：Delete useless data items.vbs
'版本：1.0
'版權：floodzhu (floodzhu@hotmail.com)，2005.1.6
'功能：遍歷概念模型，把無用的Data Items刪除。
'*****************************************************************************
dim index
index = 0

dim model 'current model
set model = ActiveModel

If (model Is Nothing) Then
   MsgBox "當前沒有活動的模型。"
ElseIf Not model.IsKindOf(PdCDM.cls_Model) Then
   MsgBox "當前模型不是概念模型。"
Else
   View model
   MsgBox index & "個無用字段被刪除。"
End If

'*****************************************************************************
'函數：View
'功能：遞歸遍歷
'*****************************************************************************
sub View(folder)
   dim item
   for each item in folder.DataItems
      if not item.IsShortCut then
         Visit item
      end if
   next
  
   '對子目錄進行遞歸
   dim subFolder
   for each subFolder in folder.Packages
      View subFolder
   next
end sub

'*****************************************************************************
'函數：Visit
'功能：處理節點
'*****************************************************************************
sub Visit(node)
 if node.UsedBy="" then
      node.delete
      index = index + 1
   end if
end sub