監控網頁中元素的事件

對編寫腳本熟悉的讀者都知道頁面中可以添加腳本響應元素的事件，例如超鏈接的OnClick事件，圖片的OnMouseMove事件，我們也可以使VB程序響應這些事件。下面是一個VB響應頁面中按鈕的Click事件的代碼：
首先建立一個新工程，在Form1中加入一個Webbrowser控件，然后在Form1中加入以下代碼：

Option Explicit

Public Sub Some_Procedure()
MsgBox "你點擊了按鈕."
End Sub

Private Sub Form_Load()
'下載空頁面
WebBrowser1.Navigate2 "about:blank"
End Sub

Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
'建立事件響應類
Dim cfForward As clsForward

'定義在瀏覽器中顯示的HTML代碼，其中包含一個按鈕btnMyButton
Dim sHTML As String
sHTML = "<P>This is some text.</P>"
sHTML = sHTML & "<P>And here is a button.</P>"
sHTML = sHTML & "<BUTTON ID=btnMyButton>"
sHTML = sHTML & "Click this button.</BUTTON>"

'將HTML代碼寫入瀏覽器
WebBrowser1.Document.body.innerHTML = sHTML

'將事件響應類連接到頁面的按鈕btnMyButton上
Set cfForward = New clsForward
cfForward.Set_Destination Me, "Some_Procedure"
WebBrowser1.Document.All("btnMyButton").onclick = cfForward
End Sub

向工程中添加一個Class Module，Class Module的Name屬性設定為clsForward，在clsForward中添加以下代碼：

Option Explicit

Dim oObject As Object
Dim sMethod As String
Dim bInstantiated As Boolean

Private Sub Class_Initialize()
bInstantiated = False
End Sub

Public Sub Set_Destination(oInObject As Object, sInMethod As String)
Set oObject = oInObject
sMethod = sInMethod
bInstantiated = True
End Sub

Public Sub My_Default_Method()
If bInstantiated Then
CallByName oObject, sMethod, VbMethod
End If
End Sub

運行程序，點擊Webbrowser中的“Click this button”按鈕。程序就會彈出消息框提示“你點擊了按鈕.”

www.applevb.com